home *** CD-ROM | disk | FTP | other *** search
/ Commodore Disk User Volume 2 #4 / Commodore_Disk_User_Vol.2_4_1989_-.d64 / sound fx demo (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  3KB  |  139 lines
  1. 100 rem *****************************
  2. 110 rem *  sound fx kit basic demo  *
  3. 120 rem *---------------------------*
  4. 130 rem *  by n.higgins january 89  *
  5. 140 rem *---------------------------*
  6. 150 rem *  uses an fx player with   *
  7. 160 rem *  a start address of 49152 *
  8. 170 rem *  ($c000).                 *
  9. 180 rem *---------------------------*
  10. 190 rem * to play these effects in  *
  11. 200 rem * the fx kit then select    *
  12. 210 rem * 'load data file' from the *
  13. 220 rem * main menu and load the    *
  14. 230 rem * file :-'demo edit data'.  *
  15. 240 rem * then go straight to the   *
  16. 250 rem * mixer option.             *
  17. 260 rem *---------------------------*
  18. 270 rem * you dont have to play fx  *
  19. 280 rem * exactly like this program *
  20. 290 rem * you can just poke each    *
  21. 300 rem * number like:              *
  22. 310 rem *                           *
  23. 320 rem *     poke 679,2            *
  24. 330 rem *     poke 680,3            *
  25. 340 rem *     poke 681,4            *
  26. 350 rem *                           *
  27. 360 rem *****************************
  28. 370 rem
  29. 380 rem + first load machine code player+
  30. 390 rem
  31. 400 f=f+1
  32. 410 iff=1thenload"basic player",8,1
  33. 420 rem
  34. 430 rem * array (mix) holds all the effects as in the kits mixer *
  35. 440 rem * (voices) = voice1 control *
  36. 450 rem
  37. 460 dim mix(77):voices=679
  38. 470 rem
  39. 480 for i=0to77
  40. 490 readj:mix(i)=j:next
  41. 500 rem
  42. 510 rem * turn fx player on *
  43. 520 rem
  44. 530 sys49152
  45. 540 rem
  46. 550 rem * setup the screen etc *
  47. 560 rem
  48. 570 gosub1340
  49. 580 rem
  50. 590 rem ***** wait for keypress *****
  51. 600 rem * if _ then turn player off *
  52. 610 rem * and end the program.      *
  53. 620 rem * else only accept a-z.     *
  54. 630 rem *****************************
  55. 640 rem
  56. 650 geta$:ifa$="_"then sys49168:print"[147]":end
  57. 660 ifa$<"a"ora$>"z"then650
  58. 670 rem
  59. 680 rem * convert into mix no. *
  60. 690 rem
  61. 700 fx=(asc(a$)-65)*3
  62. 710 rem
  63. 720 rem *****************************
  64. 730 rem * clear all registers ready *
  65. 740 rem * for the next effect.[you  *
  66. 750 rem * may not need to do this   *
  67. 760 rem * every time,especially if  *
  68. 770 rem * you use just 1 voice]     *
  69. 780 rem *****************************
  70. 790 rem
  71. 800 sys49657
  72. 810 rem
  73. 820 rem ******************************
  74. 830 rem * poke each fx number of the *
  75. 840 rem * chosen mix into its voice  *
  76. 850 rem * location.same as:-         *
  77. 860 rem *                            *
  78. 870 rem *  poke 679,fx no  [voice 1] *
  79. 880 rem *  poke 680,fx no  [voice 2] *
  80. 890 rem *  poke 681,fx no  [voice 3] *
  81. 900 rem ******************************
  82. 910 rem
  83. 920 rem
  84. 930 fori=0to2
  85. 940 poke voices+i,mix(fx+i)
  86. 950 next
  87. 960 goto650
  88. 970 rem
  89. 980 rem ****************************
  90. 990 rem * data holds the fx number *
  91. 1000 rem * for each voice.          *
  92. 1010 rem * stored as in the mixer   *
  93. 1020 rem ****************************
  94. 1030 rem
  95. 1040 rem
  96. 1050 data 0,2,1
  97. 1060 data 0,0,3
  98. 1070 data 0,2,4
  99. 1080 data 0,0,5
  100. 1090 data 0,7,6
  101. 1100 data 0,8,9
  102. 1110 data 0,14,13
  103. 1120 data 16,16,16
  104. 1130 data 10,10,11
  105. 1140 data 15,0,0
  106. 1150 data 0,18,17
  107. 1160 data 0,0,19
  108. 1170 data 20,0,21
  109. 1180 data 22,23,24
  110. 1190 data 25,0,0
  111. 1200 data 26,0,21
  112. 1210 data 27,0,28
  113. 1220 data 0,29,30
  114. 1230 data 31,0,0
  115. 1240 data 32,0,0
  116. 1250 data 6,0,0
  117. 1260 data 8,0,0
  118. 1270 data 14,0,0
  119. 1280 data 22,0,0
  120. 1290 data 10,10,12
  121. 1300 data 29,0,0
  122. 1310 rem
  123. 1320 rem * screen messages *
  124. 1330 rem
  125. 1340 poke53281,0:poke53280,0
  126. 1350 print"[147][158]            the sound fx kit"
  127. 1360 print"            ----------------"
  128. 1370 print"[158]              by n.higgins"
  129. 1380 print"[154]       playing effects from basic"
  130. 1390 print"[152]this is a demo showing how you can"
  131. 1400 print"easily play sound effects from your"
  132. 1410 print"own basic programs."
  133. 1420 print"to find out how to do it,simply"
  134. 1430 print"'list' this program and read the"
  135. 1440 print"instructions in the magazine."
  136. 1450 print"[154]          press a key from a-z"
  137. 1460 print"              or _ to stop."
  138. 1470 return
  139.